<div class="notebook">

<div class="nb-cell markdown" name="md1">
# 07.01. Grammatiken in Prolog

Testet die folgenden Grammatiken  aus, indem ihr euch jeweils den Trace für den Satz "die katze jagt keine maus" anschaut. Bitte benutzt immer nur das Anfragefeld direkt unter der Grammatik und setzt eurer Anfrage ein ``trace,`` voraus.
</div>

<div class="nb-cell markdown" name="md2">
## Grammatik 1 ohne Listen
</div>

<div class="nb-cell program" name="p1">
% Grammatik 1 ohne Listen
% Grammatikregel:

s(W1,W2,W3,W4,W5):-
    det(W1),
    n(W2),
    v(W3),
    det(W4),
    n(W5).

% Lexikon:
det(eine).
det(die).
det(keine).
n(maus).
n(katze).
v(jagt).
v(klaut).
</div>

<div class="nb-cell query" name="q1">

</div>

<div class="nb-cell markdown" name="md3">
## Grammatik 2 mit Listen und append/3 am Ende
</div>

<div class="nb-cell program" name="p2">
% Grammatik 2 mit Listen und append/3 am Ende
% Grammatikregeln,
% append/3 am Ende:

s(L3):-
    np(L1),
    vp(L2),
    append(L1,L2,L3).
 
 np(L3):-
    det(L1),
    n(L2),
    append(L1,L2,L3).
    
vp(L3):-
    v(L1),
    np(L2),
    append(L1,L2,L3).
    
%Lexikon:
det([eine]).
det([die]).
det([keine]).
n([maus]).
n([katze]).
v([jagt]).
v([klaut]).
</div>

<div class="nb-cell query" name="q2">

</div>

<div class="nb-cell markdown" name="md4">
## Grammatik 3 mit Listen und append/3 am Anfang
</div>

<div class="nb-cell program" name="p3">
% Grammatik 3 mit Listen und append/3 am Anfang
% Grammatikregeln,
% append/3 am Anfang:
s(L3):-
    append(L1,L2,L3),
    np(L1),
    vp(L2).

 
 np(L3):-
    append(L1,L2,L3),
    det(L1),
    n(L2).

    
vp(L3):-
    append(L1,L2,L3),
    v(L1),
    np(L2).
    
%Lexikon:
det([eine]).
det([die]).
det([keine]).
n([maus]).
n([katze]).
v([jagt]).
v([klaut]).
</div>

<div class="nb-cell query" name="q3">

</div>

<div class="nb-cell markdown" name="md5">
## Grammatik 4 mit Differenzlisten
</div>

<div class="nb-cell program" name="p4">
% Grammatik 4 mit Differenzlisten
% Grammatikregeln:
s(A,C):-
    np(A,B),
    vp(B,C).
np(A,C):-
    det(A,B),
    n(B,C).
vp(A,C):-
    v(A,B),
    np(B,C).
    
%Lexikon:
det([eine|A],A).
det([die|A],A).
det([keine|A],A).
n([maus|A],A).
n([katze|A],A).
v([jagt|A],A).
v([klaut|A],A).
</div>

<div class="nb-cell query" name="q4">

</div>

<div class="nb-cell markdown" name="md6">
## Grammatik 5 als DCG
</div>

<div class="nb-cell program" name="p5">
% Grammatik 5 als DCG
% Grammatikregeln:
s --&gt; np, vp.
np --&gt; det, n.
vp --&gt; v, np.

%Lexikon:
det --&gt; [eine].
det --&gt; [die].
det --&gt; [keine].
n --&gt; [maus].
n --&gt; [katze].
v --&gt; [jagt].
v --&gt; [klaut].
</div>

<div class="nb-cell query" name="q5">

</div>

</div>